PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libconfig-git
pkgver=1.8.2.r2.ge485a72
pkgrel=1
pkgdesc="C/C++ library for processing configuration files"
arch=('i686' 'x86_64')
url="https://hyperrealm.github.io/libconfig/"
license=('LGPL-2.1-or-later')
depends=('glibc' 'libgcc' 'libstdc++')
makedepends=('git' 'cmake' 'texinfo')
provides=("libconfig=$pkgver")
conflicts=('libconfig')
source=("git+https://github.com/hyperrealm/libconfig.git")
sha256sums=('SKIP')


pkgver() {
  cd "libconfig"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libconfig"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    ./
  cmake --build "_build"
}

check() {
  cd "libconfig"

  #cmake --build "_build" --target test
}

package() {
  cd "libconfig"

  DESTDIR="$pkgdir" cmake --install "_build"
}